home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 23 / CU Amiga - Super CD-ROM 23 (June 1998).iso / CreatingGames / GameCreators / TADS / std.t < prev    next >
Encoding:
Text File  |  1996-11-22  |  11.9 KB  |  357 lines
  1. /* Copyright (c) 1989, 1991 by Michael J. Roberts.  All Rights Reserved. */
  2. /*
  3. Name
  4.   std.t   - standard default adventure definitions
  5.   Version 1.2
  6.   
  7.   This file is part of TADS:  The Text Adventure Development System.
  8.   Please see the file LICENSE.DOC (which should be part of the TADS
  9.   distribution) for information on using this file.
  10.  
  11.   This file provides some simple definitions for objects and functions
  12.   that are required by TADS, but not defined in the file "adv.t".
  13.   The definitions in std.t are suitable for use while a game is
  14.   being written, but you will probably find that you will want to
  15.   customize the definitions in this file for your game when the
  16.   game is nearing completion.  This file is intended to help you
  17.   get started more quickly by providing basic definitions for these
  18.   functions and objects.
  19.  
  20.   When you decide to customize these functions and objects for
  21.   your game, be sure to remove the inclusion of std.t to avoid
  22.   duplicate definitions.
  23. */
  24.  
  25. /* parse with normal TADS operators */
  26. #pragma C-
  27.  
  28. /*
  29.  *   Pre-declare all functions, so the compiler knows they are functions.
  30.  *   (This is only really necessary when a function will be referenced
  31.  *   as a daemon or fuse before it is defined; however, it doesn't hurt
  32.  *   anything to pre-declare all of them.)
  33.  */
  34. die: function;
  35. scoreRank: function;
  36. init: function;
  37. terminate: function;
  38. pardon: function;
  39. sleepDaemon: function;
  40. eatDaemon: function;
  41. darkTravel: function;
  42.  
  43. /*
  44.  *   The die() function is called when the player dies.  It tells the
  45.  *   player how well he has done (with his score), and asks if he'd
  46.  *   like to start over (the alternative being quitting the game).
  47.  */
  48. die: function
  49. {
  50.     "\b*** You have died ***\b";
  51.     scoreRank();
  52.     "\bYou may restore a saved game, start over, quit, or undo
  53.     the current command.\n";
  54.     while ( 1 )
  55.     {
  56.         local resp;
  57.  
  58.     "\nPlease enter RESTORE, RESTART, QUIT, or UNDO: >";
  59.         resp := upper(input());
  60.         if ( resp = 'RESTORE' )
  61.     {
  62.         resp := askfile( 'File to restore' );
  63.         if ( resp = nil ) "Restore failed. ";
  64.         else if ( restore( resp )) "Restore failed. ";
  65.         else
  66.         {
  67.             Me.location.lookAround(true);
  68.             scoreStatus( global.score, global.turnsofar );
  69.         abort;
  70.         }
  71.     }
  72.         else if ( resp = 'RESTART' )
  73.     {
  74.         scoreStatus( 0, 0 );
  75.             restart();
  76.     }
  77.     else if ( resp = 'QUIT' )
  78.         {
  79.         terminate();
  80.             quit();
  81.         abort;
  82.         }
  83.     else if (resp = 'UNDO')
  84.     {
  85.         if (undo())
  86.         {
  87.         "(Undoing one command)\b";
  88.         Me.location.lookAround(true);
  89.             scoreStatus(global.score, global.turnsofar);
  90.         abort;
  91.         }
  92.         else
  93.         "Sorry, no undo information is available. ";
  94.     }
  95.     }
  96. }
  97.  
  98. /*
  99.  *   The scoreRank() function displays how well the player is doing.
  100.  *   This default definition doesn't do anything aside from displaying
  101.  *   the current and maximum scores.  Some game designers like to
  102.  *   provide a ranking that goes with various scores ("Novice Adventurer,"
  103.  *   "Expert," and so forth); this is the place to do so if desired.
  104.  *
  105.  *   Note that "global.maxscore" defines the maximum number of points
  106.  *   possible in the game; change the property in the "global" object
  107.  *   if necessary.
  108.  */
  109. scoreRank: function
  110. {
  111.     "In a total of "; say( global.turnsofar );
  112.     " turns, you have achieved a score of ";
  113.     say( global.score ); " points out of a possible ";
  114.     say( global.maxscore ); ".\n";
  115. }
  116.  
  117. /*
  118.  *   The init() function is run at the very beginning of the game.
  119.  *   It should display the introductory text for the game, start
  120.  *   any needed daemons and fuses, and move the player's actor ("Me")
  121.  *   to the initial room, which defaults here to "startroom".
  122.  */
  123. init: function
  124. {
  125.     // put introductory text here
  126.     
  127.     version.sdesc;                // display the game's name and version number
  128.  
  129.     setdaemon( turncount, nil );               // start the turn counter daemon
  130.     setdaemon( sleepDaemon, nil );                    // start the sleep daemon
  131.     setdaemon( eatDaemon, nil );                     // start the hunger daemon
  132.     Me.location := startroom;                // move player to initial location
  133.     startroom.lookAround( true );                    // show player where he is
  134.     startroom.isseen := true;                  // note that we've seen the room
  135.     scoreStatus(0, 0);                          // initialize the score display
  136. }
  137.  
  138. /*
  139.  *   preinit() is called after compiling the game, before it is written
  140.  *   to the binary game file.  It performs all the initialization that can
  141.  *   be done statically before storing the game in the file, which speeds
  142.  *   loading the game, since all this work has been done ahead of time.
  143.  *
  144.  *   This routine puts all lamp objects (those objects with islamp = true) into
  145.  *   the list global.lamplist.  This list is consulted when determining whether
  146.  *   a dark room contains any light sources.
  147.  */
  148. preinit: function
  149. {
  150.     local o;
  151.     
  152.     global.lamplist := [];
  153.     o := firstobj();
  154.     while( o <> nil )
  155.     {
  156.         if ( o.islamp ) global.lamplist := global.lamplist + o;
  157.         o := nextobj( o );
  158.     }
  159.     initSearch();
  160. }
  161.  
  162. /*
  163.  *   The terminate() function is called just before the game ends.  It
  164.  *   generally displays a good-bye message.  The default version does
  165.  *   nothing.  Note that this function is called only when the game is
  166.  *   about to exit, NOT after dying, before a restart, or anywhere else.
  167.  */
  168. terminate: function
  169. {
  170. }
  171.  
  172. /*
  173.  *   The pardon() function is called any time the player enters a blank
  174.  *   line.  The function generally just prints a message ("Speak up" or
  175.  *   some such).  This default version just says "I beg your pardon?"
  176.  */
  177. pardon: function
  178. {
  179.     "I beg your pardon? ";
  180. }
  181.  
  182. /*
  183.  *   This function is a daemon, started by init(), that monitors how long
  184.  *   it has been since the player slept.  It provides warnings for a while
  185.  *   before the player gets completely exhausted, and causes the player
  186.  *   to pass out and sleep when it has been too long.  The only penalty
  187.  *   exacted if the player passes out is that he drops all his possessions.
  188.  *   Some games might also wish to consider the effects of several hours
  189.  *   having passed; for example, the time-without-food count might be
  190.  *   increased accordingly.
  191.  */
  192. sleepDaemon: function( parm )
  193. {
  194.     local a, s;
  195.  
  196.     global.awakeTime := global.awakeTime + 1;
  197.     a := global.awakeTime;
  198.     s := global.sleepTime;
  199.  
  200.     if ( a = s or a = s+10 or a = s+20 )
  201.         "\bYou're feeling a bit drowsy; you should find a
  202.         comfortable place to sleep. ";
  203.     else if ( a = s+25 or a = s+30 )
  204.         "\bYou really should find someplace to sleep soon, or
  205.         you'll probably pass out from exhaustion. ";
  206.     else if ( a >= s+35 )
  207.     {
  208.       global.awakeTime := 0;
  209.       if ( Me.location.isbed or Me.location.ischair )
  210.       {
  211.         "\bYou find yourself unable to stay awake any longer.
  212.         Fortunately, you are << Me.location.statusPrep >> <<
  213.     Me.location.adesc >>, so you gently slip off into
  214.         unconsciousness.
  215.         \b* * * * *
  216.         \bYou awake some time later, feeling refreshed. ";
  217.       }
  218.       else
  219.       {
  220.         local itemRem, thisItem;
  221.  
  222.         "\bYou find yourself unable to stay awake any longer.
  223.         You pass out, falling to the ground.
  224.         \b* * * * *
  225.         \bYou awaken, feeling somewhat the worse for wear.
  226.         You get up and dust yourself off. ";
  227.         itemRem := Me.contents;
  228.         while (car( itemRem ))
  229.         {
  230.             thisItem := car( itemRem );
  231.             if ( not thisItem.isworn )
  232.             thisItem.moveInto( Me.location );
  233.             itemRem := cdr( itemRem );
  234.         }
  235.       }
  236.     }
  237. }
  238.  
  239. /*
  240.  *   This function is a daemon, set running by init(), which monitors how
  241.  *   long it has been since the player has had anything to eat.  It will
  242.  *   provide warnings for some time prior to the player's expiring from
  243.  *   hunger, and will kill the player if he should go too long without
  244.  *   heeding these warnings.
  245.  */
  246. eatDaemon: function( parm )
  247. {
  248.     local e, l;
  249.  
  250.     global.lastMealTime := global.lastMealTime + 1;
  251.     e := global.eatTime;
  252.     l := global.lastMealTime;
  253.  
  254.     if ( l = e or l = e+5 or l = e+10 )
  255.         "\bYou're feeling a bit peckish. Perhaps it would be a good
  256.         time to find something to eat. ";
  257.     else if ( l = e+15 or l = e+20 or l = e+25 )
  258.         "\bYou're feeling really hungry. You should find some food
  259.         soon or you'll pass out from lack of nutrition. ";
  260.     else if ( l=e+30 or l = e+35 )
  261.         "\bYou can't go much longer without food. ";
  262.     else if ( l >= e+40 )
  263.     {
  264.         "\bYou simply can't go on any longer without food. You perish from
  265.         lack of nutrition. ";
  266.         die();
  267.     }
  268. }
  269.  
  270. /*
  271.  *   The numObj object is used to convey a number to the game whenever
  272.  *   the player uses a number in his command.  For example, "turn dial
  273.  *   to 621" results in an indirect object of numObj, with its "value"
  274.  *   property set to 621.
  275.  */
  276. numObj: basicNumObj  // use default definition from adv.t
  277. ;
  278.  
  279. /*
  280.  *   strObj works like numObj, but for strings.  So, a player command of
  281.  *     type "hello" on the keyboard
  282.  *   will result in a direct object of strObj, with its "value" property
  283.  *   set to the string 'hello'.
  284.  *
  285.  *   Note that, because a string direct object is used in the save, restore,
  286.  *   and script commands, this object must handle those commands.
  287.  */
  288. strObj: basicStrObj     // use default definition from adv.t
  289. ;
  290.  
  291. /*
  292.  *   The "global" object is the dumping ground for any data items that
  293.  *   don't fit very well into any other objects.  The properties of this
  294.  *   object that are particularly important to the objects and functions
  295.  *   are defined here; if you replace this object, but keep other parts
  296.  *   of this file, be sure to include the properties defined here.
  297.  *
  298.  *   Note that awakeTime is set to zero; if you wish the player to start
  299.  *   out tired, just move it up around the sleepTime value (which specifies
  300.  *   the interval between sleeping).  The same goes for lastMealTime; move
  301.  *   it up to around eatTime if you want the player to start out hungry.
  302.  *   With both of these values, the player only starts getting warnings
  303.  *   when the elapsed time (awakeTime, lastMealTime) reaches the interval
  304.  *   (sleepTime, eatTime); the player isn't actually required to eat or
  305.  *   sleep until several warnings have been issued.  Look at the eatDaemon
  306.  *   and sleepDaemon functions for details of the timing.
  307.  */
  308. global: object
  309.     turnsofar = 0                            // no turns have transpired so far
  310.     score = 0                            // no points have been accumulated yet
  311.     maxscore = 100                                    // maximum possible score
  312.     verbose = nil                             // we are currently in TERSE mode
  313.     awakeTime = 0               // time that has elapsed since the player slept
  314.     sleepTime = 400     // interval between sleeping times (longest time awake)
  315.     lastMealTime = 0              // time that has elapsed since the player ate
  316.     eatTime = 200         // interval between meals (longest time without food)
  317.     lamplist = []              // list of all known light providers in the game
  318. ;
  319.  
  320. /*
  321.  *   The "version" object defines, via its "sdesc" property, the name and
  322.  *   version number of the game.  Change this to a suitable name for your
  323.  *   game.
  324.  */
  325. version: object
  326.     sdesc = "A TADS Adventure
  327.       \n Developed with TADS, the Text Adventure Development System.\n"
  328. ;
  329.  
  330. /*
  331.  *   "Me" is the player's actor.  Pick up the default definition, basicMe,
  332.  *   from "adv.t".
  333.  */
  334. Me: basicMe
  335. ;
  336.  
  337. /*
  338.  *   darkTravel() is called whenever the player attempts to move from a dark
  339.  *   location into another dark location.  By default, it just says "You
  340.  *   stumble around in the dark," but it could certainly cast the player into
  341.  *   the jaws of a grue, whatever that is...
  342.  */
  343. darkTravel: function
  344. {
  345.     "You stumble around in the dark, and don't get anywhere. ";
  346. }
  347.  
  348. /*
  349.  *   goToSleep - carries out the task of falling asleep.  We just display
  350.  *   a message to this effect.
  351.  */
  352. goToSleep: function
  353. {
  354.     "***\bYou wake up some time later, feeling refreshed. ";
  355.     global.awakeTime := 0;
  356. }
  357.